<< Overview - Distribution Tests Distribution-Tests ST_shapirowilk >>
samplestat >> samplestat > Distribution-Tests > ST_ivplot

ST_ivplot

Individual value plot for one or more data sets.

Syntax

ST_ivplot(data)
ST_ivplot(data, names)
ST_ivplot(data, names, marker)
ST_ivplot(data, names, marker, offset)
ST_ivplot(data, names, marker, offset, tolerance)

Arguments

data:

numeric vector, list of numeric vectors or numeric matrix which each column represents one data set

names:

Labels of the data sets as a string vector, e.g. "Sample 1" or ["Lot 1", "Lot 2"]

marker:

Scilab marker, optionally combined with a standard color code. Markers ".", ",", "o", "x", "+", "*", "s", or "d". Colors "r", "g", "b", "c", "m", "y", "k", or "w". Marker and color may be given in either order, e.g. ".r", "r.", "oc", or "co". A color alone uses the default marker ".". "," is accepted as an alias for the point marker ".".

offset:

Horizontal distance between identical values. Recommended range 0.02 to 0.12. Default 0.02.

tolerance:

Two values are considered equal if their difference is less than or equal to tolerance. Default 0, meaning only exactly identical values.

Description

Individual value plots (IVP) are well suited for evaluating and comparing distributions of sample data. A IVP displays a point for the actual value of each observation in a group, making it easy to identify outliers and see the dispersion of the distribution. A IVP is especially recommended for small sample sizes in comparison to histograms, box-plots and QQ-plots, which need at least 20 values to be significant.

Therefore IVPs are well suited to test very small sample sizes on normal distribution when outliers or ties could be present and the Shapiro-Wilk distribution test cannot be reliably applied.

Examples

// Single data record
data = [9.999 9.998 10.002 10.000 10.001 10.000];
scf();
clf();
ST_ivplot(data, "Charge A");
ylabel("Sample");
title("Individual-Value-Plot from single data record");

// Multi data records in a list & different sample sizes
data1 = [9.999 9.998 10.002 10.000 10.001 10.000 10. 10. 10. 10. 10. 10. ];
data2 = [10.003 10.001 10.001 10.004 9.997];
data3 = [9.995 10.000 10.000 10.000 10.002 10.004 10.006];
scf();
clf();
ST_ivplot( ..
list(data1, data2, data3), ..
["Lot A", "Lot B", "Lot C"], ..
"d");
ylabel("Concentration [mg/L]");
title("Multi data records in a list & different sample sizes");

//  Multi data record in a matrix
data4 = [
10.1  10.4  10.0;
10.2  10.3  10.1;
10.2  10.5  10.1;
10.4  10.4  10.2;
10.3  10.6  10.3
];
scf();
clf();
ST_ivplot(data4, ["1", "2", "3"], "o", 0.04);
ylabel("Samples");
title("Multi data record in a matrix")

// Tolerance limit specified for nearly identical values
// tolerance=0.000001
data5 = [
10.0000000
10.0000001
9.9999999
10.1000000
];
scf();
clf();
ST_ivplot(data5, "Sample", "x", 0.02, 0.000001);
title("Tolerance limit specified for nearly identical values")

See also


Report an issue
<< Overview - Distribution Tests Distribution-Tests ST_shapirowilk >>